[JAVA] Führen Sie modulare Projekttests in Gradle aus (JUnit5 + TestFX).

Ich machte einen Umweg, bis ich es konnte, also mach dir eine Notiz. Die Umgebung ist IntelliJ. Ich benutze Eclipse nicht, also weiß ich es nicht.

Sie können org.javamodularity.moduleplugin verwenden, um modulare Projekte ohne spezielle Konfiguration zu testen. Wenn Sie jedoch TestFX verwenden Musste das Modul mit der JVM-Option '- add-opens' sichtbar machen.

Unten finden Sie ein Beispiel für build.gradle

build.gradle

plugins {
    id 'application'
    id 'org.openjfx.javafxplugin' version '0.0.7'
    id 'org.beryx.jlink' version '2.10.4'
    id "org.javamodularity.moduleplugin" version "1.5.0"
}

group 'com.sample'
version '1.0-SNAPSHOT'

sourceCompatibility = 1.12

mainClassName = "$moduleName/com.sample.Main"

repositories {
    mavenCentral()
}

//Javafx Plug-In-Einstellungen
javafx {
    version = "12"
    modules = ['javafx.controls', 'javafx.fxml']
}

//Einstellungen für das jlink-Plug-In
jlink {
    options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
    launcher{
        name = "$moduleName"
    }
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.3.1'
    testImplementation 'org.junit.jupiter:junit-jupiter-params:5.3.1'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.3.1'
    testCompile group: 'org.testfx', name: 'testfx-junit5', version: '4.0.15-alpha'
}

test {
    useJUnitPlatform()
    testLogging {
        events "passed", "skipped", "failed"
    }
    //Optionen für TestFX
    jvmArgs = [
            '--add-opens', "$moduleName/com.sample.foo=org.testfx.junit5",
            '--add-opens', 'javafx.graphics/com.sun.javafx.application=org.testfx'
    ]
}