Comment monter l'emplacement du fichier de commandes via WSL2 et démarrer le conteneur Docker

Qu'est-ce que c'est?

Nous suggérons comment double-cliquer sur un fichier de commandes et le monter en tant que volume WSL2 lors du démarrage avec Docker pour Windows.

Lecteur supposé

--Les personnes qui ont installé la version WSL2 de docker --Les personnes qui ont été prévenues de mauvaises performances lors du montage du volume au démarrage du docker --Les personnes qui ont du mal à démarrer WSL à chaque fois qu'elles démarrent Docker

Conclusion

L'exemple suivant démarre une image de conteneur avec un nom de fichier de commandes. Si vous modifiez le nom du fichier de commandes, l'image du conteneur à démarrer changera.

buildpack-deps.bat

@setlocal
@set "WORK=/root/workspace"

@cd /d "%~dp0"
@set "IMG=%~n0"

@if "%~0" == "%~f0" set "pause_if_error=@if errorlevel 1 pause"

@for %%i in ( "%CD%" ) do @set "WSL2CD=%%~di"
@for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do @call set "WSL2CD=%%WSL2CD:%%~i=%%~i%%"
@for %%i in ( "%CD%" ) do @call set "WSL2CD=%%WSL2CD:~0,-1%%%%~pnxi"
@set "WSL2CD=/mnt/%WSL2CD:\=/%"

wsl -e docker run -it --rm -w "%WORK%" -v "%WSL2CD%:%WORK%" %IMG% %*
%pause_if_error%
@exit /b %errorlevel%

Le point de montage est écrit directement dans @ set" WORK = / root / workspace ", donc réécrivez-le comme il convient. Pour corriger l'image, réécrivez @set" IMG =% ~ n0 ". Puisque la distribution de wsl n'est pas spécifiée, si vous voulez la spécifier, ajoutez l'option de wsl de manière appropriée.

Environnement de confirmation

Windows10 1909 Docker version 19.03.13, build 4484c46d9d

Commentaire

Lors du démarrage de docker, utilisez la commande wsl. Le volume spécifie le chemin sur wsl. Ce que fait l'opération de WSL2CD est le processus de conversion du chemin Windows en chemin WSL.

Avec cela, l'avertissement disparaît et c'est rafraîchissant!

référence

• Invite de commandes (cmd.exe) Note privée